פונקציית CHOOSE ב-Excel

תיאור

תחביר וארגומנטים

שימוש ודוגמאות

• דוגמה 1 - שימוש בסיסי: שימוש בפונקציית CHOOSE לבדה לבחירת ערך מרשימת ארגומנטים
• דוגמה 2 – החזרת תוצאות שונות על סמך תנאים מרובים
• דוגמה 3 – החזרת תוצאות מחושבות שונות על סמך תנאים
• דוגמה 4 – בחירה אקראית מתוך רשימה
• דוגמה 5 – שילוב פונקציות CHOOSE ו-VLOOKUP כדי להחזיר ערך בעמודה השמאלית
• דוגמה 6 – החזרת יום בשבוע או חודש על סמך תאריך נתון
• דוגמה 7 – החזרת תאריך של יום עבודה/סופ"ש הבא על סמך היום הנוכחי

תיאור

הפונקציה CHOOSE מחזירה ערך מתוך רשימת ערכים על סמך מספר אינדקס נתון. לדוגמה, CHOOSE(3,"Apple","Peach","Orange") מחזירה Orange, המספר האינדקס הוא 3, ו-Orange הוא הערך השלישי אחרי מספר האינדקס בפונקציה.

תחביר וארגומנטים

תחביר נוסחה

ארגומנטים

Value1, value2… יכולים להיות מספרים, טקסטים, נוסחאות, הפניות לתאים, או שמות מוגדרים.

ערך החזרה

הפונקציה CHOOSE מחזירה ערך מתוך רשימה על סמך המיקום הנתון.

שימוש ודוגמאות

בחלק זה, אני מציג כמה דוגמאות פשוטות אך מייצגות להסבר השימוש בפונקציית CHOOSE.

דוגמה 1 - שימוש בסיסי: שימוש CHOOSE פונקציה לבדה לבחירת ערך מרשימת ארגומנטים

נוסחה 1:

=CHOOSE(3,"a","b","c","d")

החזרה: c, שהוא הארגומנט השלישי אחרי index_num של 3 בפונקציית CHOOSE.

הערה: השתמשו במרכאות כפולות סביב הערך אם הוא טקסט.

נוסחה 2:

=CHOOSE(2,A1,A2,A3,A4)

החזרה: Kate, הערך של A2. מכיוון שה-index_num הוא 2, ו-A2 הוא הערך השני בפונקציית CHOOSE.

נוסחה 3:

=CHOOSE(4,8,9,7,6)

החזרה: 6, הארגומנט הרביעי ברשימה בפונקציה.

דוגמה 2 – החזרת תוצאות שונות על סמך תנאים מרובים

נניח שיש לכם רשימה של סטיות עבור כל מוצר שצריכות להיות מסומנות על סמך תנאים כפי שמוצג בתמונה למטה.

בדרך כלל, אתם יכולים להשתמש בפונקציית IF כדי להתמודד עם הבעיה, אך כאן אני מציג כיצד להשתמש בפונקציית CHOOSE כדי לפתור את הבעיה בקלות.

נוסחה:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

הסבר:

(B7>0)+(B7>1)+(B7>5): ה-index_num, B7 הוא 2, שהוא גדול מ-0 ו-1 אך קטן מ-5, אז אנו מקבלים את התוצאה הבאה:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

כפי שאנו יודעים, True = 1, False = 0, אז הנוסחה יכולה להיחשב כך:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

ואז

=CHOOSE(2,"Top","Middle","Bottom")

תוצאה: Middle

דוגמה 3 – החזרת תוצאות מחושבות שונות על סמך תנאים

נניח שאתם צריכים לחשב את ההנחות עבור כל מוצר על סמך הכמות והמחיר כפי שמוצג בתמונה למטה:

נוסחה:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

הסבר:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 הוא 102, שהוא גדול מ-100 אך קטן מ-201, אז בחלק זה, הוא מחזיר את התוצאה הבאה:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

ואז

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: הערכים שאפשר לבחור מהם, ההנחה שווה למחיר * כמות * אחוז הנחה, מכיוון שה-index_num כאן הוא 2, הוא בוחר B8*C8*0.2

החזרה: 102*2*0.2=40.8

דוגמה 4 – בחירה אקראית מתוך רשימה

ב-Excel, לפעמים, ייתכן שתצטרכו לבחור באופן אקראי ערך מתוך רשימה נתונה, הפונקציה CHOOSE יכולה לפתור את המשימה.

בחירת ערך אחד באקראי מתוך רשימה:

נוסחה:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

הסבר:

RANDBETWEEN(1,5): index_num, קבלת מספר אקראי בין 1 ל-5

$D$2,$D$3,$D$4,$D$5,$D$6: הרשימה של הערכים שאפשר לבחור מהם

דוגמה 5 – שילוב פונקציות CHOOSE ו-VLOOKUP כדי להחזיר ערך בעמודה השמאלית

באופן כללי, אנו משתמשים בפונקציית VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) כדי להחזיר ערך על סמך ערך נתון מתוך טווח טבלה. אך עם VLOOKUP הפונקציה, היא תחזיר ערך שגיאה כאשר העמודה לה החזרה נמצאת משמאל לעמודת החיפוש כפי שמוצג בתמונה למטה:

במקרה כזה, ניתן לשלב את הפונקציה CHOOSE עם פונקציית VLOOKUP כדי לפתור את הבעיה.

נוסחה:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

הסבר:

CHOOSE({1,2},B1:B7,A1:A7): כארגומנט table_range בפונקציית VLOOKUP. {1,2} אומר להציג 1 או 2 כארגומנט index_num על סמך הארגומנט col_num בפונקציית VLOOKUP. כאן, ה-col_num בפונקציית VLOOKUP הוא 2, אז CHOOSE הפונקציה מוצגת כך CHOOSE(2, B1:B7,A1:A7), כלומר לבחור ערך מתוך A1:A7.

דוגמה 6 – החזרת יום בשבוע או חודש על סמך תאריך נתון

עם הפונקציה CHOOSE, אתם גם יכולים להחזיר את יום השבוע או החודש הרלוונטיים על סמך תאריך נתון.

נוסחה 1: החזרת יום בשבוע לפי תאריך

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

הסבר:

WEEKDAY(): הארגומנט index_num, כדי לקבל את מספר יום השבוע של התאריך הנתון, למשל, WEEKDAY(A5) מחזיר 6, אז הארגומנט index_num הוא 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": רשימת ערכים, מתחילים ב-“Sunday” מכיוון שמספר יום “1” מצביע על “Sunday”.

נוסחה 2: החזרת חודש לפי תאריך

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

הסבר:

MONTH(): ארגומנט index_num, שמקבל את מספר החודש מהתאריך הנתון, למשל, MONTH(A5) מחזיר 3.

דוגמה 7 – החזרת תאריך של יום עבודה/סופ"ש הבא על סמך היום הנוכחי

בעבודה יומיומית, אולי תרצו לחשב את יום העבודה או סופ"ש הבא על סמך היום הנוכחי. כאן הפונקציה CHOOSE יכולה לעזור.

לדוגמה, היום הוא 20/12/2018, חמישי, כעת עליכם לקבל את יום העבודה הבא ואת סוף השבוע.

נוסחה 1: קבלת תאריך של היום

=TODAY()

תוצאה: 20/12/2018

נוסחה 2: קבלת מספר יום השבוע של היום

=WEEKDAY(TODAY())

תוצאה: 5 (כאשר היום הוא 20/12/2018)

רשימת מספרי ימי השבוע כפי שמוצג בתמונה למטה:

נוסחה 3: קבלת יום העבודה הבא

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

הסבר:

Today(): מחזיר את התאריך הנוכחי

WEEKDAY(TODAY()): ארגומנט index_num בפונקציית CHOOSE, מקבל את מספר יום השבוע של היום, למשל, ראשון הוא 1, שני הוא 2…

1,1,1,1,1,3,2: רשימת ערכים בפונקציית CHOOSE. למשל, אם weekday(today()) מחזיר 1 (ראשון), הוא בוחר 1 מתוך רשימת הערכים, אז הנוסחה המלאה משתנה ל-=Today()+1, מה שאומר להוסיף יום אחד ולהחזיר את יום שני הבא. אם weekday(today()) מחזיר 6 (שישי), הוא בוחר 3 מתוך רשימת הערכים, מכיוון ששישי נמצא 3 ימים לפני יום שני הבא.

תוצאה (כאשר היום הוא 20/12/2018):

=20/12/2018+CHOOSE(5,1,1,1,1,1,3,2)

=12/20/2018+1

=12/21/2018

נוסחה 4: קבלת יום סופ"ש הבא

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

הסבר:

6,5,4,3,2,1,1: רשימת ערכים בפונקציית CHOOSE. למשל, אם weekday(today()) מחזיר 1 (ראשון), הוא בוחר 6 מתוך רשימת הערכים, אז הנוסחה המלאה משתנה ל-=Today()+6, מה שאומר להוסיף 6 ימים ולהחזיר את יום שבת הבא.

תוצאה:

=20/12/2018+CHOOSE(5,6,5,4,3,2,1,1)

=12/20/2018+2

=12/22/2018

קובץ לדוגמה