Skip to main content

גלה היום את הגרסה החדשה והחינמית של Kutools עבור Outlook!

סיכום ערכים לפי מספר שבוע או יום בשבוע ב-Excel

Author: Siluvia Last Modified: 2025-05-30

המדריך הזה מציג נוסחאות שלב אחר שלב כדי לעזור לך לסכם ערכים בטווח מסוים על בסיס מספר השבוע או היום בשבוע שצוין ב-Excel.

כיצד לסכם ערכים לפי מספר שבוע ב-Excel?
כיצד לסכם ערכים לפי יום בשבוע ב-Excel?

כיצד לסכם ערכים לפי מספר שבוע ב-Excel?

כפי שמוצג בתמונה למטה, כדי לסכם את הערכים בעמודת הסכום על בסיס התאריכים שבהם נופל מספר שבוע נתון, אנו מספקים שתי נוסחאות.

doc-sum-by-week-number-weekday-1

נוסחאות כלליות

=SUMIFS( טווח_ערכים, טווח_עמודת_עזר, מספר_שבוע)

=SUMPRODUCT(--(WEEKNUM(טווח_תאריכים+0,1)=מספר_שבוע),טווח_ערכים)

ארגומנטים

Value_range: הטווח של הערכים שברצונך לסכם על בסיס מספר השבוע;
Helper_column_range: הטווח של מספרי השבוע שהוצאו מתוך התאריך;
Week_number: מספר השבוע המשמש כקריטריון לסיכום הערכים.

איך להשתמש בנוסחה זו?

שימוש בנוסחת SUMIFS ובעמודת עזר

כדי להשתמש בנוסחת SUMIFS, קודם כל עליך להחיל את הפונקציה WEEKNUM כדי ליצור עמודת עזר לחישוב מספרי השבוע המתאימים לתאריכים בעמודת התאריך.

=WEEKNUM (serial_num, [return_type])

הפונקציה WEEKNUM מחזירה את מספר השבוע עבור התאריך הנתון בשנה.

1. במקרה זה, אני בוחר תא (F5) ליד הערך הראשון בעמודת הסכום.

2. הזן את הנוסחה הבאה לתוכו והקש על מקש Enter כדי לקבל את מספר השבוע של התאריך הראשון. בחר בתא התוצאה ולאחר מכן גרור את ידית האוטומטי שלה למטה כדי לקבל את מספרי השבוע האחרים. ראה צילום מסך:

=WEEKNUM(C5)

doc-sum-by-week-number-weekday-2

3. בחר תא כדי להציג את הסכום הכולל, הזן את הנוסחה הבאה לתוכו והקש על מקש Enter. בחר בתא התוצאה, גרור את ידית האוטומטי שלה למטה כדי לקבל את התוצאות האחרות.

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

שימוש בנוסחת SUMPRODUCT

אין צורך ליצור עמודת עזר כאשר משתמשים בנוסחת SUMPROFUCT כדי לפתור את הבעיה.

1. בחר תא ריק, הזן את הנוסחה הבאה לתוכו והקש על מקש Enter.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. בחר בתא התוצאה, גרור את ידית האוטומטי שלה למטה כדי לקבל את התוצאות האחרות לפי הצורך.

doc-sum-by-week-number-weekday-4

הסבר לנוסחה

=SUMIFS($E$5:$E$14, $F$5:$F$14, H6)

לאחר חישוב מספרי השבוע עם הפונקציה WEEKNUM, הפונקציה SUMIFS מסכמת את הערכים בטווח E5:E14 אם מספרי השבוע בעמודת העזר F5:F14 תואמים לשבוע הנתון ב-H6.

=SUMPRODUCT(--(WEEKNUM($C$5:$C$14+0,1)=G6),$E$5:$E$14)

WEEKNUM($C$5:$C$14+0,1): הפונקציה WEEKNUM מחשבת כל מספר שבוע של התאריכים בטווח C5:C14, ומחזירה מערך כזה: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: כאן משווים כל מספר שבוע במערך עם מספר השבוע הנתון ב-G6, ומחזירים מערך חדש: {TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE};
--{TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}: שני סימני מינוס אלו ממירים את “TRUE” ו-“FALSE” ל-1 ול-0. כאן תקבל מערך חדש כמו זה: {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: כל זוג ערכים במערכים מוכפלים יחד ומחזירים {1428;2010;0;0;0;0;0;0;0;0};
SUMPRODUCT({1428;2010;0;0;0;0;0;0;0;0}): הפונקציה SUMPRODUCT מסכמת את כל המספרים במערך ומחזירה את התוצאה הסופית 1428+2010=3438.

כיצד לסכם ערכים לפי יום בשבוע ב-Excel?

כפי שמוצג בתמונה למטה, כדי לסכם ערכים בעמודת הסכום לפי יום בשבוע מסוים ב-Excel, ניתן להחיל את הפונקציה SUMPRODUCT יחד עם הפונקציה WEEKDAY כדי לעשות זאת.

במקרה זה, מכיוון שאנו צריכים לסכם את הסכום הכולל עבור כל יום בשבוע, לפני החלת הנוסחה, אנו יוצרים עמודת עזר עם המספרים 1 עד 7 כדי לציין בנפרד מיום שני עד יום ראשון.

doc-sum-by-week-number-weekday-6

נוסחה כללית

=SUMPRODUCT((WEEKDAY(טווח_תאריכים,2)=מספר_יום_שבוע)*טווח_ערכים)

ארגומנטים

Date_range: טווח התאריכים שבו ברצונך להעריך את ימי השבוע הנתונים;
Value_range: טווח הערכים שברצונך לסכם על בסיס יום בשבוע;
2: המספר 2 מייצג מספרים מ-1 (שני) עד 7 (ראשון);
Weekday_number: מספר יום השבוע המשמש כקריטריון לסיכום הערכים. יכול להיות הפניה לתא או מספר בין 1 ל-7.

איך להשתמש בנוסחה זו?

1. בחר תא ליד תא המספר 1. כאן אני בוחר I6.

2. העתק או הזן את הנוסחה הבאה לתוכו והקש על מקש Enter. בחר בתא התוצאה, ולאחר מכן גרור את ידית האוטומטי שלה למטה כדי לקבל את התוצאות עבור ימי השבוע האחרים.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

הערה: אם אתה צריך רק לסכם ערכים על בסיס יום בשבוע אחד מסוים כמו יום שישי, אתה יכול להכניס ישירות את המספר 5 בנוסחה באופן הבא.

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=5)*$E$5:$E$14)

הסבר לנוסחה

=SUMPRODUCT((WEEKDAY($C$5:$C$14,2)=H6)*$E$5:$E$14)

WEEKDAY($C$5:$C$14,2): הפונקציה WEEKDAY מחזירה מספרים שלמים מ-1 עד 7 לייצג את יום השבוע מיום שני עד יום ראשון בטווח C5:C14: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: כאן משווים כל יום בשבוע במערך עם מספר יום השבוע הנתון ב-H6, ומחזירים מערך חדש: {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE};
{FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE;FALSE;FALSE}*$E$5:$E$14: כאן TRUE ו-FALSE מומרות ל-1 ו-0, ולאחר מכן מוכפלות בערכים ב-E5:E14 כדי להחזיר את המערך: {0;0;2288;0;0;0;1325;0;0;0};
SUMPRODUCT{0;0;2288;0;0;0;1325;0;0;0}: הפונקציה SUMPRODUCT מסכמת את כל המספרים במערך ומחזירה את התוצאה הסופית 2288+1325=3613.

פונקציות קשורות

פונקציית WEEKNUM ב-Excel
הפונקציה SUMIFS ב-Excel מחזירה את מספר השבוע עבור התאריך הנתון בשנה, שמתחילה לספור שבועות מה-1 בינואר.

פונקציית SUMPRODUCT ב-Excel
ניתן להשתמש בפונקציית SUMPRODUCT ב-Excel כדי להכפיל שתי עמודות או יותר או מערכים יחד, ולאחר מכן לקבל את סכום המכפלות.

פונקציית WEEKDAY ב-Excel
הפונקציה EOMONTH ב-Excel מחזירה מספר שלם מ-1 עד 7 לייצג את יום השבוע עבור תאריך נתון ב-Excel.

נוסחאות קשורות

סיכום ערכים לפי חודש (עם או בלי שנה)
המדריך הזה מציג שתי נוסחאות בהרחבה כדי לעזור לסכם ערכים לפי חודש ושנה מסוימים או לסכם ערכים לפי חודש מסוים תוך התעלמות מהשנה ב-Excel.

סיכום ערכים לפי השבוע של תאריך נתון
המדריך הזה דן כיצד לסכם ערכים לפי השבוע שבו נופל תאריך נתון.

סיכום כל n שורות או עמודות בטווח
המדריך הזה מסביר שתי נוסחאות המבוססות על הפונקציות SUM ו-OFFSET כדי לסכם כל n שורות או עמודות בטווח מסוים ב-Excel.

סיכום כל שורה או עמודה n בטווח
המדריך הזה עומד להראות לך כיצד ליצור נוסחה המבוססת על הפונקציות SUMPRODUCT, MOD ו-COLUMN כדי לסכם כל שורה או עמודה n בטווח ב-Excel.

הכלים הטובים ביותר לפריון עבודה ב-Office

Kutools for Excel - עוזר לך להבליט את עצמך מהקהל

🤖 עוזר KUTOOLS AI: מהפכה בניתוח נתונים בהתבסס על: ביצוע אינטליגנטי   |  יצירת קוד  |  יצירת נוסחאות מותאמות אישית  |  ניתוח נתונים ויצירת תרשימים  |  קריאה לפונקציות Kutools…
תכונות פופולריות: מצא, הדגש או זיהוי כפילויות  |  מחיקת שורות ריקות  |  שילוב עמודות או תאים ללא אובדן נתונים  |  עיגול ללא נוסחה ...
VLookup מתקדם: קריטריונים מרובים  |  ערכים מרובים  |  על פני מספר גליונות  |  חיפוש עמום...
רשימה נפתחת מתקדמת: רשימה נפתחת קלה  |  רשימה נפתחת תלוית  |  רשימה נפתחת עם בחירה מרובה...
מנהל עמודות: הוספת מספר מסוים של עמודות  |  הזזת עמודות  |  שינוי מצב הנראות של עמודות מוסתרות  |  השוואת עמודות לבחירת תאים זהים ושונים ...
תכונות מובילות: מיקוד רשת  |  תצוגת עיצוב  |  שורת נוסחאות משופרת  |  מנהל חוברת עבודה וגיליונות | ספריית טקסט אוטומטי (טקסט אוטומטי)  |  בורר תאריך  |  מיזוג גליונות עבודה  |  הצפנה/פענוח תאים  |  שליחת דוא"ל לפי רשימה  |  סינון מתקדם  |  סינון מיוחד (סנן תאים עם גופן מודגש/נטוי/קו חוצה...) ...
15 סטים כלים מובילים:  12 כלים לטקסט (הוסף טקסט, מחק תווים מסוימים ...)  |  מעל 50 סוגי תרשימים (תרשים גאנט ...)  |  מעל 40 נוסחאות מעשיות (חישוב גיל על פי תאריך לידה ...)  |  19 כלים להכנסה (הכנס קוד QR, הכנס תמונה ממסלול ...)  |  12 כלים להמרה (המרה למילים, המרת מטבע ...)  |  7 כלים למיזוג והפרדה (מיזוג מתקדם של שורות, הפרדת תאים באקסל ...)  |  ... ועוד

Kutools for Excel מצויד ביותר מ-300 תכונות, מבטיח שהדברים שאתה זקוק להם הם רק במרחק לחיצה אחת...

Office Tab - אפשר קריאה ועריכה בטאבים בתוך Microsoft Office (כולל Excel)

  • תוך שנייה אחת תוכל לעבור בין עשרות מסמכים פתוחים!
  • חוסך מאות הקלקות בעכבר עבורך מדי יום, תאמר שלום ליד עכבר.
  • מעלה את התפוקה שלך ב-50% בעת צפייה ועריכת מסמכים מרובים.
  • מביא את הטאבים האפקטיביים ל-Office (כולל Excel), בדיוק כמו ב-Chrome, Edge ו-Firefox.