קבל את הערך הראשון שאינו ריק בעמודה או בשורה

כדי לחלץ את הערך הראשון (התא הראשון שאינו ריק, תוך התעלמות משגיאות) מטווח של עמודה אחת או שורה אחת, ניתן להשתמש בנוסחה המבוססת על פונקציות INDEX ו-MATCH. עם זאת, אם אינך רוצה להתעלם משגיאות מתוך הטווח שלך, תוכל להוסיף את הפונקציה ISBLANK לנוסחה לעיל.

קבל את הערך הראשון שאינו ריק בעמודה או בשורה תוך התעלמות משגיאות
קבל את הערך הראשון שאינו ריק בעמודה או בשורה כולל שגיאות

קבל את הערך הראשון שאינו ריק בעמודה או בשורה תוך התעלמות משגיאות

כדי לחלץ את הערך הראשון שאינו ריק ברשימה כפי שמוצג למעלה תוך התעלמות משגיאות, ניתן להשתמש בפונקציית INDEX בתוך פונקציית MATCH "INDEX((range<>0),0)" כדי למצוא תאים שאינם ריקים. לאחר מכן השתמש בפונקציית MATCH כדי לאתר את מיקום התא הראשון שאינו ריק. המיקום יועבר לפונקציית INDEX החיצונית כדי לחלץ את הערך במיקום זה.

תחביר כללי

=INDEX(range,MATCH(TRUE,INDEX((range<>0),0),0))

כדי לחלץ את הערך הראשון שאינו ריק ברשימה תוך התעלמות משגיאות, אנא העתק או הזן את הנוסחה הבאה בתא E4, והקש Enter כדי לקבל את התוצאה:

=INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))

הסבר לנוסחה

=INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0))

• INDEX((B4:B15<>0),0) : קטע זה מעריך כל ערך בטווח B4:B15. אם תא הוא ריק, הוא יחזיר FALSE; אם תא מכיל שגיאה, הקטע יחזיר את השגיאה עצמה; ואם תא מכיל מספר או טקסט, יוחזר TRUE. מכיוון שהארגומנט row_num של נוסחת INDEX זו הוא 0, הקטע יחזיר את מערך הערכים עבור כל העמודה כך: {FALSE;#REF!;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE}.
• MATCH(TRUE,MATCH(TRUE,INDEX((B4:B15<>0),0),0),0) = MATCH(TRUE,MATCH(TRUE,{FALSE;#REF!;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE;TRUE;TRUE;FALSE;TRUE},0),0): הסוג ההתאמה 0 מכריח את פונקציית MATCH להחזיר את מיקום הTRUE המדויק הראשון במערך. לכן, הפונקציה תחזיר 3.
• INDEX(B4:B15,MATCH(TRUE,INDEX((B4:B15<>0),0),0)) = INDEX(B4:B15,3): לאחר מכן פונקציית INDEX מחזירה את הערך השלישי בטווח B4:B15, שהוא extendoffice.

קבל את הערך הראשון שאינו ריק בעמודה או בשורה כולל שגיאות

כדי לחלץ את הערך הראשון שאינו ריק ברשימה כולל שגיאות, אתה יכול פשוט להשתמש בפונקציית ISBLANK כדי לבדוק את התאים ברשימה אם הם ריקים או לא. לאחר מכן INDEX יחזיר את הערך הראשון שאינו ריק בהתאם למיקום ש-MATCH סיפק.

תחביר כללי

=INDEX(range,MATCH(FALSE,ISBLANK(range),0))

√ הערה: זוהי נוסחה מסוג מערך שדורשת ממך להזין באמצעות Ctrl + Shift + Enter, למעט ב-Excel 365 וב-Excel 2021.

כדי לחלץ את הערך הראשון שאינו ריק ברשימה כולל שגיאות, אנא העתק או הזן את הנוסחה הבאה בתא E7, והקש Ctrl + Shift + Enter כדי לקבל את התוצאה:

=INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

הסבר לנוסחה

=INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0))

• ISBLANK(B4:B15): פונקציית ISBLANK בודקת אם התאים בטווח B4:B15 הם ריקים או לא. אם כן, יוחזר TRUE; אם לא, יוחזר FALSE. לכן, הפונקציה תיצור מערך כזה: {TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}.
• MATCH(FALSE,MATCH(FALSE, ISBLANK(B4:B15) ,0),0) = MATCH(FALSE,MATCH(FALSE, {TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE} ,0),0) : סוג ההתאמה 0 מכריח את פונקציית MATCH להחזיר את מיקום ה-FALSE המדויק הראשון במערך. לכן, הפונקציה תחזיר 2.
• INDEX(B4:B15,MATCH(FALSE,ISBLANK(B4:B15),0)) = INDEX(B4:B15,2): לאחר מכן פונקציית INDEX מחזירה את הערך השני בטווח B4:B15, שהוא #REF!.

פונקציות קשורות

נוסחאות קשורות