Skip to main content

גלה היום את הגרסה החדשה והחינמית של Kutools עבור Outlook!

ספירת ערכים ייחודיים ושונים בקלות – 7 דוגמאות

Author: Xiaoyang Last Modified: 2025-05-30

באופן רגיל, ב-Excel, הערכים הייחודיים הם הערכים שמופיעים רק פעם אחת ברשימה ללא כל כפילויות, והערכים השונים הם כל הערכים השונים (ערכים ייחודיים + המופעים הכפולים הראשונים). כאשר עובדים על מערך נתונים גדול, ייתכן שתצטרכו לספור את מספר הערכים הייחודיים והשונים בין הכפילויות מתוך רשימת תאים כפי שמוצג בסcreenshot למטה. מדריך זה יציג כמה טיפים מהירים לספירת ערכים ייחודיים ושונים ב-Excel.

Count unique values or distinct values in a list

ספירת ערכים ייחודיים ב-Excel

ספירת ערכים שונים (ייחודיים והמופעים הכפולים הראשונים) ב-Excel

ספירת ערכים ייחודיים ב-Excel

הפרק הזה ידון במספר דוגמאות נוסחאות לספירת מספר הערכים הייחודיים, כולל טקסט ומספרים ברשימה.

ספירת ערכים ייחודיים עם נוסחאות

נניח שיש לי רשימת שמות המכילה כמה שמות כפולים בתוך רשימת השמות. כעת, אני צריך לקבל את מספר השמות הייחודיים בלבד (שממולאו בצבע צהוב) כפי שמוצג בסcreenshot למטה:

sample data

כדי לפתור את הבעיה הזו, הנוסחה המערך הבאה יכולה לעזור לכם:

שלב 1: הזנת נוסחה

הזינו או העתיקו את הנוסחה הבאה לתא ריק שבו תרצו להציג את התוצאה:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
 הערה: בנוסחה לעיל, "A2:A12" הוא טווח הנתונים שבו תרצו לספור ערכים ייחודיים.

שלב 2: לחצו על מקשי Ctrl + Shift + Enter כדי לקבל את התוצאה הנכונה:

Count unique values with formula

הערות:

  1. אם רשימת התאים שלכם מכילה סוגים אחרים של נתונים, כגון מספרים, ערכי בוליאני, ערכי שגיאה וכו', בעת השימוש בנוסחה לעיל, היא תקבל את מספר הערכים הייחודיים ללא קשר לסוג הנתונים.
  2. כאשר טווח הנתונים מכיל תאים ריקים, נוסחה זו תכלול את התאים הריקים.
  3. לספור רק את הערכים הטקסטואליים הייחודיים אם יש סוגי נתונים נוספים, אנא השתמשו בנוסחת המערך הבאה, ולאחר מכן לחצו על מקשי "Ctrl" + "Shift" + "Enter" כדי להחזיר את התוצאה: 
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. לספור רק מספרים ייחודיים מתוך רשימת תאים המכילה כל סוג של נתונים, אנא השתמשו בנוסחת המערך הבאה, ולאחר מכן לחצו על מקשי "Ctrl" + "Shift" + "Enter" כדי להחזיר את התוצאה: 
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

ספירת ערכים ייחודיים בכמה לחיצות עם Kutools for Excel

יכול להיות שזה יהיה קשה עבורכם לזכור את הנוסחאות כשיהיה עליכם להשתמש בהן שוב. אבל, אם יש לכם "Kutools for Excel", עם האפשרות "Count Unique Values" ב"Formulas Helper", תוכלו לקבל את התוצאה בכמה לחיצות בלבד. ראו את הדמו למטה:

  1. לחצו על תא כדי להציג את התוצאה;
  2. אפשרו את התכונה הזאת על ידי לחיצה על "Kutools" > "Formula Helper" > "Formula Helper" > "Statistical" > "Count unique values";
  3. בחרו את רשימת הנתונים > "OK".
    Count unique values with kutools
טיפים:
  1. כדי להשתמש בתכונה זו, עליכם להוריד ולהתקין את Kutools for Excel.
  2. התכונה "Formulas Helper" אוסף יותר מ-40 נוסחאות נפוצות לשימוש, כגון "Extract unique values", "Extract cells with unique values(include the first duplicates)", "Count the number of values separated by comma", "Sum based on same text", ועוד...

ספירת ערכים ייחודיים ב-Excel 365/2021 עם נוסחאות

אם אתם משתמשים ב-Excel 365 או Excel 2021, יש פונקציה חדשה בשם UNIQUE שיכולה לעזור לכם ליצור נוסחאות פשוטות יותר לספירת ערכים ייחודיים בקבוצת נתונים.

לדוגמה, כדי לספור את מספר השמות הייחודיים בטווח A2:A12, אנא הזינו את הנוסחה הבאה:

שלב 1: העתיקו או הזינו את הנוסחה הבאה

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
הערה: בנוסחה זו, "A2:A12" הוא טווח הנתונים שבו תרצו לספור ערכים ייחודיים.

שלב 2: לחצו על מקש Enter כדי לקבל את התוצאה:

Count unique values in Excel 365/2021 with formula

טיפים:

  1. אם טווח הנתונים מכיל סוגים אחרים של נתונים, כגון טקסט, מספרים, ערכי בוליאני, ערכי שגיאה וכו', נוסחה זו תקבל את מספר הערכים הייחודיים ללא קשר לסוג הנתונים.
  2. הנוסחה לעיל תספור ערכים ייחודיים כולל תאים ריקים, אם תרצו להוציא את הריקים, אנא השתמשו בנוסחה הבאה, ויש צורך רק ללחוץ על מקש "Enter": 
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

ספירת ערכים שונים (ייחודיים והמופעים הכפולים הראשונים) ב-Excel

כדי לספור את הערכים השונים (ערכים ייחודיים והמופעים הכפולים הראשונים) ברשימת תאים, כאן, אני אציג נוסחאות נוספות כדי להשיג את המשימה הזו.

ספירת ערכים שונים עם נוסחאות

ב-Excel, תוכלו להחיל אחת מהנוסחאות הבאות כדי להחזיר את מספר הערכים השונים.

שלב 1: הזינו אחת מהנוסחאות הבאות

נוסחה 1: לאחר הזנת הנוסחה, לחצו על מקש "Enter".

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

נוסחה 2: לאחר הזנת הנוסחה, לחצו על מקשי "Ctrl" + "Shift" + "Enter".

=SUM(1/COUNTIF(A2:A12,A2:A12))
הערה: בנוסחאות אלו, "A2:A12" הוא טווח הנתונים שבו תרצו לספור ערכים שונים.

תוצאה:

Count distinct values with formula

טיפים:

  1. אם טווח הנתונים מכיל סוגים אחרים של נתונים, כגון מספרים, ערכי בוליאני, ערכי שגיאה וכו', נוסחה זו תקבל את הערכים השונים ללא קשר לסוג הנתונים.
  2. כאשר משתמשים בנוסחה לעיל, תקבלו ערך שגיאה #DIV/0 אם טווח הנתונים מכיל תאים ריקים. כדי לתקן ולהתעלם מהתאים הריקים, עליכם להחיל אחת מהנוסחאות הבאות:
    נוסחה 1: לאחר הזנת הנוסחה, לחצו על מקש "Enter". 
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    נוסחה 2: לאחר הזנת הנוסחה, לחצו על מקשי "Ctrl" + "Shift" + "Enter". 
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Count distinct values exclude blank cells with formula

  3. כדי לקבל את מספר הערכים הטקסטואליים השונים בלבד בתוך רשימה של נתונים, אנא השתמשו בנוסחת המערך הבאה, ולחצו על מקשי "Ctrl" + "Shift" + "Enter" כדי לקבל את התוצאה: 
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. כדי לספור רק ערכים מספריים שונים, אנא השתמשו בנוסחת המערך הבאה, ולחצו על מקשי "Ctrl" + "Shift" + "Enter" כדי לקבל את התוצאה: 
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

ספירת ערכים שונים בכמה לחיצות עם Kutools for Excel

אם עליכם להחיל את הנוסחאות לעיתים קרובות בקובץ העבודה שלכם, יכול להיות שזה יהיה קשה עבורכם לזכור את הנוסחאות כשיהיה עליכם להשתמש בהן שוב. אבל, אם יש לכם "Kutools for Excel", עם האפשרות "Count cells with unique values (include the first duplicate)" ב"Formulas Helper", תוכלו לקבל את התוצאה בכמה לחיצות בלבד. ראו את הדמו למטה:

  1. לחצו על תא כדי להציג את התוצאה;
  2. אפשרו את התכונה הזאת על ידי לחיצה על "Kutools" > "Formula Helper" > "Statistical" > "Count unique cells with unique values (include the first duplicate)";
  3. בחרו את רשימת הנתונים > "OK".
    Count distinct values with kutools
טיפים:
  1. כדי להשתמש בתכונה זו, עליכם להוריד ולהתקין את Kutools for Excel.
  2. התכונה "Formulas Helper" אוסף יותר מ-40 נוסחאות נפוצות לשימוש, כגון "Extract unique values", "Extract cells with unique values(include the first duplicates)", "Count the number of values separated by comma", "Sum based on same text", ועוד...

ספירת ערכים שונים עם PivotTable

ב-Excel, גם טבלת צירים יכולה לעזור לקבל את מספר הערכים השונים מתוך רשימת נתונים, אנא עשו את הצעדים הבאים:

שלב 1: יצירת טבלת צירים

  1. בחרו את טווח הנתונים, ולאחר מכן לחצו על "Insert" > "PivotTable" מסרגל הכלים, ראו את הסcreenshot:
    create a pivottable for selected data
  2. בתיבת הדו-שיח "PivotTable" שהופיעה:
    (1). בחרו גיליון עבודה חדש או קיים שבו תרצו להציב את טבלת הצירים;
    (2). לאחר מכן סמנו את תיבת הסימון "Add this data to the Data Model".
    (3). לאחר מכן לחצו על כפתור "OK".
    set options in PivotTable from table or range dialog box

שלב 2: סידור השדה ובבחירת אפשרות Count Distinct

  1.  חלונית "PivotTable Fields" מוצגת, גררו את השדה "Names" לאזור "Values", ראו את הדמו למטה:
    Arrange the field for pivottable
  2. לאחר מכן, לחצו על תפריט הנפתח של "Count of Names", ובחרו "Value Field Settings", ראו את הסcreenshot:
    click value Field Settings option
  3. ואז, תיבת דו-שיח "Value Field Settings" תיפתח, בחרו "Distinct Count" מתיבת הרשימה מתחת ללשונית "Summarize Value By", ולחצו על כפתור "OK", ראו את הסcreenshot:
    select Distinct Count option

תוצאה:

עכשיו, טבלת הצירים שנוצרה תציג את הספירה השונה של טווח הנתונים כפי שמוצג בסcreenshot למטה:

PivotTable result to count distinct values

טיפים:

  1. אם אתם מעדכנים את נתוני המקור, כדי לקבל את הספירה האחרונה, כל שעליכם לעשות הוא ללחוץ ימני על טבלת הצירים ולבחור באפשרות "Refresh".
  2. אפשרות "Distinct Count" זמינה רק ב-Excel 2013 והגרסאות החדשות יותר.

ספירת ערכים שונים ב-Excel 365/2021 עם נוסחאות

ב-Excel 365 או Excel 2021, תוכלו להשתמש בפונקציה החדשה UNIQUE עם הפונקציה COUNTA הרגילה כדי ליצור נוסחה קלה.

אנא העתיקו או הזינו את הנוסחה הבאה לתא ריק, ולחצו על מקש "Enter" כדי לקבל את התוצאה:

=COUNTA(UNIQUE(A2:A12))
הערה: בנוסחה זו, "A2:A12" הוא טווח הנתונים שבו תרצו לספור ערכים שונים.

Count distinct values in Excel 365/2021 with formula

טיפים:

  1. אם טווח הנתונים מכיל סוגים אחרים של נתונים, כגון טקסט, מספרים, ערכי בוליאני, ערכי שגיאה וכו', נוסחה זו תספור את מספר הערכים השונים ללא קשר לסוג הנתונים.
  2. הנוסחה לעיל תספור ערכים שונים כולל תאים ריקים, אם תרצו להוציא את הריקים, אנא השתמשו בנוסחה הבאה, ולחצו על מקש "Enter" כדי לקבל את התוצאה: 
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Count distinct values in Excel 365/2021 with formula exclude blank cells

מאמרים קשורים:

  • ספירת ערכים ייחודיים בטבלת צירים
  • כברירת מחדל, כאשר אנו יוצרים טבלת צירים על בסיס טווח נתונים שמכיל כמה ערכים כפולים, כל הרשומות ייספרו גם כן, אך לפעמים, אנחנו רוצים רק לספור את הערכים הייחודיים על בסיס עמודה אחת כדי לקבל את התוצאה הנכונה. במאמר זה, אני אדבר על איך לספור את הערכים הייחודיים בטבלת הצירים.
  • ספירת ערכים ייחודיים בעמודה מסוננת
  • אם יש לכם רשימת שמות שמכילה כמה כפילויות בעמודה מסוננת, ועכשיו, אתם רוצים לספור את מספר השמות הייחודיים בלבד מתוך הרשימה המסוננת הזו. האם יש לכם פתרונות טובים כדי להתמודד עם המשימה הזו במהירות ב-Excel?
  • ספירת ערכים ייחודיים עם קריטריונים מרובים
  • כאן יש טווח נתונים שמכיל מספר שמות, פרויקטים ומיקומים, ומה שצריך לעשות הוא למצוא את השמות שמתאימים לקריטריונים שלי, ואז לספור כל שם מתאים פעם אחת בלבד כפי שמוצג בסcreenshot למטה. האם יש לכם טריקים לפתרון המשימה הזו? במאמר זה, אני אציג את הטריקים.
  • צירוף ערכים ייחודיים
  • אם יש לי רשימה ארוכה של ערכים שמכילה כמה נתונים כפולים, עכשיו, אני רוצה למצוא רק את הערכים הייחודיים ואז לצרף אותם לתוך תא אחד. כיצד אוכל להתמודד עם הבעיה הזו במהירות ובקלות ב-Excel?